soldatov.info

Блог Солдатова Евгения

Периодическое резервное копирование баз 1с 7.7

оставить комментарий

Внимание!

В данной статье я буду описывать метод резервного копирования баз данных 1с 7.7, необходимость в использовании которого возникла в процессе работы на одном из предприятий, где, как это часто бывает, реализовать резервное копирование иначе достаточно сложно.

Все перечисленные действия будем делать непосредственно на сервере.

Создадим скрипт v7backup.cmd в котором укажем:

REM Выключим вывод ненужной информации
@ECHO OFF
 
REM Зададим текущую дату и время в переменную DATE_NOW
SET DATE_NOW=%date:~6,4%_%date:~3,2%_%date:~0,2%
REM Укажем путь к исполняемому файлу 1с в переменную PROGRAM_BIN
SET PROGRAM_BIN="C:\Program Files\1Cv77\BIN\1cv7s.exe"
 
REM Создадим каталог для сохранения текущего архива
MKDIR C:\1c_backup\%DATE_NOW%
 
REM Укажем название БД, в нашем случае TS
SET CURRENT_DB=TS
REM Укажем путь к БД, в нашем случае папка 1c на сервере SRV
SET CURRENT_DB_CMD="\\SRV\1c\%CURRENT_DB%\"
REM Укажем имя пользователя к БД
SET CURRENT_DB_USERNAME="admin"
REM Укажем пароль к БД
SET CURRENT_DB_PASSWORD="admin"
REM Укажем результатирующее имя файла
SET CURRENT_FILENAME=%CURRENT_DB%_%DATE_NOW%.zip
 
REM Зупаскаем процедуру создания резервной копии
%PROGRAM_BIN% CONFIG /D%CURRENT_DB_CMD% /N%CURRENT_DB_USERNAME% /P%CURRENT_DB_PASSWORD% /@ C:\1c_backup\config.prm
 
REM Перемещаем созданный архив в нужный нам каталог
MOVE /Y C:\1c_backup\backup.zip C:\1c_backup\%DATE_NOW%\%CURRENT_FILENAME%
 
REM Удаляем старые архивы, ключ /D -30 говорит о том, что удаляем каталоги и файлы в них старше 30 дней
FORFILES /P C:\_1c_backup\ /D -30 /C "CMD /C RMDIR /S /Q @path"

Помимо данного файла нам понадобится файл config.prm следующего содержания:

[General]
Quit=1
UnloadData=1
 
[UnloadData]
UnloadToFile=C:\1c_backup\backup
IncludeUserDef=0

Данный файл (config.prm) необходимо поместить в каталог C:\1c_backup\.

Основной плюс данного метода резервного копирования заключается в том, что в случае возникновения необходимости восстановить базу, достаточно будет взять полученный файл, например «1c_general_2011_01_01.zip» и при помощи стандартного инструмента восстановления, запустить необходимую базу данных на любом компьютере.

Автор: Евгений

Дата: 04.01.2012 в 16:29:30

Leave a Reply

You must be logged in to post a comment.